# Al-5Q-digitizedphase60.in

# spin-5/2 anti echo and echo amplitude optimization
# versus the first-pulse duration
# in three-pulse amplitude-modulated z-filter 5QMAS,
# the second-pulse duration p2 = 4 micro seconds
# the third-pulse duration p3 = 2 micro seconds
# nested phase cycling with digitized phase for receiver

spinsys {
  channels 27Al
  nuclei   27Al
  quadrupole 1 2 3e6 0 0 0 0
}


par {
  spin_rate        5000
  variable tsw     0.25
  sw               1.0e6/tsw
  np               17
  crystal_file     rep10
  gamma_angles     10
  proton_frequency 800e6
  start_operator   I1z
  detect_operator  I1c
  verbose          1101
  variable rf      90000
  variable rf3     9300
  variable p2      4
  variable p3      2
  variable NA      10
  variable NC      6
  variable deltapA 5
  variable deltapC 1
}

proc pulseq {} {
  global par
  maxdt $par(tsw)

  acq -y
  for {set i 1} {$i < $par(np)} {incr i} {
    pulse $par(tsw) $par(rf)  $par(phA)
    store 2
    pulse $par(p2)  $par(rf)  $par(phB)
    pulse $par(p3)  $par(rf3) $par(phC)
    acq                 [expr $par(phREC) - 90]
    reset
    prop 2
  }
}

proc main {} {
  global par

  set par(phB)   0

  for {set jC 0} {$jC < $par(NC)} {incr jC} {
    set par(phC)   [expr $jC*360./$par(NC)]

    for {set jA 0} {$jA < $par(NA)} {incr jA} {
      set par(phA)   [expr $jA*360./$par(NA)]
      set par(phREC) [expr $par(deltapA)*$par(phA) + $par(deltapC)*$par(phC)]

      set g [fsimpson]
      if [info exists f] {
        fadd $f $g
        funload $g
      } else {
        set f $g
      }
    }
  }

  fsave $f $par(name).fid
  funload $f
  puts "Larmor frequency (Hz) of 27Al: "
  puts [resfreq 27Al $par(proton_frequency)]
}

#SIMP
#NP=17
#SW=4000000
#TYPE=FID
#DATA
#0 0
#-1.27794077e-09 7.88813459e-13
#-5.85462608e-07 3.71753961e-10
#-1.87286308e-05 1.189601e-08
#-0.000195623463 1.24682867e-07
#-0.00108799177 7.12467734e-07
#-0.00401184576 2.82823801e-06
#-0.0110311005 8.91894569e-06
#-0.0243512199 2.41042301e-05
#-0.0456156664 5.79859362e-05
#-0.0759948132 0.0001257905
#-0.117095148 0.000246377504
#-0.171518671 0.000435738582
#-0.241950004 0.000698431021
#-0.328952337 0.00102209844
#-0.428917153 0.00137866014
#-0.533652236 0.00173146942
#END