z-filter ±9QMAS NMR pulse program, cogwheel or nested phase cycling

z-filter ±9QMAS pulse program for spin 9/2
Contributor: Y. Millot

Home and Applets > Pulse Program > Z-Filter ±9QMAS Pulse Program

Below NMR pulse program describes the z-filter ±9QMAS (1D and 2D) experiment with cogwheel phase cycling or nested phase cycling applied to nuclei with spin 9/2.

This NMR pulse program is for Bruker Avance spectrometers.

A pure absorption 2D spectrum is obtained with the shearing transformation.

Code for Avance NMR spectrometers

; 9qzfilter.ym (XWIN-NMR 3.0)
; 01072009

;±9Q MAS pulse program for half integer spin nuclei
;ZGOPTNS (zg-options) are:
;  -DNQS9Cog ... used with I=9/2  (ns=180) cog180(0,10,1,91) = cog180(134,144,135,45)
;  -DNQS9Nesdig  used with I=9/2  (ns=180) nested phase cycling with digital receiver
;  -DNQS9Nes ..  used with I=9/2  (ns=324) nested phase cycling with standard receiver

;d1 : recycle delay
;p1 : excitation pulse at pl11
;p2 : conversion pulse at pl11
;p3 : 90 degree selective pulse at pl13
;pl1 : =120 dB
;pl11 : power level for excitation and conversion pulses
;pl13 : power level for selective pulse
;d4 : =20u, delay for z-filter 
;d0 : =3u
;in0 : 1 rotation period for synchronised experiment
;td1 : number of t1-experiments
;FnMODE : States or TPPI
;Shearing use AU program xfshear (FnMode = States) 
;ph30 ph31:r for receiver phase <> kpi/2

  ze                    ; clear memory, new data replace old data,
                        ; switch AD converter to replace mode,
                        ; perform DS before next acquisition,

1 d1                    ; recycle delay,
  10u pl11:f1           ; 10 microsecond delay,
                        ; set high power in f1 channel,
  (p1 ph1):f1           ; high-power excitation pulse,
  d0                    ; delay between pulses, t1 increment,
  (p2 ph2):f1           ; high-power conversion pulse,
  d4  pl13:f1           ; set low power in f1 channel,
  (p3 ph3):f1           ; low-power 90° pulse,
#ifdef NQS9Cog
  go=1 ph31             ; signal acquisition,
                        ; loop to 1, ns times for averaging,
#else
#ifdef NQS9Nesdig
  go=1 ph30 ph31:r      ; instruction must be in that order
                        ; signal acquisition,
                        ; loop to 1, ns times for averaging,
#else
#ifdef NQS9Nes
  go=1 ph31             ; signal acquisition,
                        ; loop to 1, ns times for averaging,
#endif
#endif
#endif
  d1 mc #0 to 1 F1PH(ip1, id0)
                        ; delay for disk I/O, store signal,
                        ; increase FID number,
                        ; delete memory data,
                        ; increment p1 pulse phase by 360°/36 
                        ; for States procedure,
                        ; increment time d0 by in0,
  exit                  ; end of the pulse program

#ifdef NQS9Cog
 ph10= (180) {0 1 2 3 4 5 6 7 8 9}^10^20^30^40^50^60^70^80^90^100^110^120^130^140^150^160^170
                        ; a series of integer numbers from 0 to 179
 ph1 = (36)   ph10*134  ; excitation pulse phase
 ph2 =        ph10*144  ; conversion pulse phase
 ph3 =        ph10*135  ; 90° selective pulse phase
 ph31=        ph10*45   ; receiver phase : (360/180)*45*m=90*m
#else
#ifdef NQS9Nesdig
 ph1 = (36)   0 2 4 6 8 10 12 14 16 18 20 22 24 26 28 30 32 34
 ph2 =        0
 ph3 = (10) {{0}*18}^1^2^3^4^5^6^7^8^9
 ph30=        ph1*9 + ph3
 ph31=        0
#else 
#ifdef NQS9Nes
 ph1 = (36)   0 2 4 6 8 10 12 14 16 18 20 22 24 26 28 30 32 34
 ph2 = (18) {{0}*18}^1^2^3^4^5^6^7^8^9^10^11^12^13^14^15^16^17
 ph3 =        0
 ph31=        ph1*9 - ph2*9
#endif
#endif
#endif

This pulse program remains valid for the third pulse with strong amplitude for better excitation of off-resonance nuclei.

[Contact me] - Last updated May 14, 2011

z-filter ±9QMAS pulse program for spin 9/2 Contributor: Y. Millot

Code for Avance NMR spectrometers

z-filter ±9QMAS pulse program for spin 9/2
Contributor: Y. Millot