1D or 2D HETCOR pulse program for TopSpin2.1

1D or 2D HETCOR pulse program for topSpin2.1 operating system

Home and Applets > Pulse Program > HPdec and CPMAS > 1D or 2D HETCOR for TopSpin2.1

Code for Avance III spectrometers with topSpin2.1 operating system

;cp2DF1PH (TopSpin 2.0)

;basic cp experiment
;written by HF 1.3.2001
;changed by JOS 05/06/03
;comments added by STE 4.4.2006

;Avance II+ version
;parameters: 
;p3 : proton 90 at power level pl12
;p15 : contact time at pl1 (f1) and pl2 (f2)
;pl1 : X power level during contact
;sp0 : proton power level during contact
;pl2 : =120dB, not used
;pl12 : decoupling power level (if not pl13)
;pl13 : special decoupliong power level
;d1 : recycle delay
;cnst21 : on resonance, usually = 0
;pcpd2 : pulse length in decoupling sequence
;cpdprg2 : cw, tppm (at pl12), or lgs, cwlg, cwlgs (LG-decoupling) 
;spnam0 : use e.g. ramp.100 for variable amplitude CP
;here pl13 is used instead of pl12)
;zgoptns : -Dfslg, -Dlacq, or blank
;in0 = inf1

;$COMMENT=basic cp experiment, arbitrary contact and decoupling schemes
;$CLASS=Solids
;$DIM=1D
;$TYPE=cross polarisation
;$SUBTYPE=simple 1D
;$OWNER=Bruker
prosol relations=<solids_cp>

#include <Avancesolids.incl>

#ifdef fslg
#include <lgcalc.incl>
;cnst20 : RF field achieved at pl13
;cnst21 : on resonance, usually = 0
;cnst22 : positive LG offset
;cnst23 : negative LG offset
;cnst24 : additional LG-offset
#endif /* fslg */
;cnst11 : to adjust t=0 for acquisition, if digmod = baseopt
"acqt0=1u*cnst11"

1 ze

2 d1 do:f2
#include <p15_prot.incl>
            ;make sure p15 does not exceed 10 msec	
            ;let supervisor change this pulseprogram if 
            ;more is needed
#ifndef lacq
            ;disable protection file for long acquisition change decoupling power !!! or you risk probe damage
            ;if you set the label lacq (ZGOPTNS -Dlacq), the protection is disabled

#include <aq_prot.incl>
            ;allows max. 50 msec acquisition time, supervisor
            ;may change  to max. 1s at less than 5 % duty cycle
            ;and reduced decoupling field
#endif

  1u fq=cnst21:f2
  (p3  ph1):f2 (1u pl12):f2
  d0
  (p15 pl1 ph2):f1 (p15:sp0 ph10):f2
  go=2 ph31 cpds2:f2             ;pl12 is used here with tppm, pl13 with cwlg, cwlgs
  1m do:f2
  10m mc #0 to 2 F1PH(ip1,id0)

HaltAcqu, 1m
exit

ph0=  0
ph1=  1 3
ph2=  0 0 2 2 1 1 3 3
ph10= 0
ph31= 0 2 2 0 1 3 3 1

[Contact me] - Last updated May 14, 2011