BABA CP/2rotations: 1D/2D CP/double quantum excitation, 2 rotor period, BABA pulse program for TopSpin2.1




Home and Applets > Pulse Program > 2Q/1Q Correlation > 1D/2D CP BABA 2 Rotations Pulse Program
Double-quantum excitation with BABA CP pulse sequence

Since non-phase cycling is applied to the BABA excitation pulse, four-phase cycling is applied to the detection pulse P1 for selecting the 0Q -> -1Q coherence order jump, and four-phase cycling is applied to the BABA reconversion pulse for filtering DQ coherences.

Avoid cross-polarization during BABA excitation and reconversion.


*** Outline ***


Code for Avance III spectrometers with topSpin2.1 operating system

;babacp2  (TopSpin 2.0)

;2D SQ-DQ correlation experiment for 2 rotor period recoupling using BABA 
;with cross polarization for weak dipole dipole couplings, compensated for
;pulse imperfections 
;M. Feike, D.E. Demco, R. Graf, J. Gottwald, S. Hafner, and H.W. Spiess JMR A 122, 214-221 (1996)
;written by JOS, 11/12/03

;Avance II+ version
;parameters:
;d1 : recycle delay
;d0 : incremented delay (2D) [1 usec]
;pl1 : for X contact pulse
;sp0 : proton power level during contact
;pl2 : =120dB, not used
;pl11 : for 90 degree X BABA pulses
;pl12 : for decoupling and excitation 1H
;pl13 : for decoulping during recoupling sequence
;p1 : 90 degree X pulse BABA
;p3 : 90 degree 1H pulse excitation
;pcpd2 : pulse length in decoupling sequence
;p15 : contact time
;cnst31 : MAS spinning frequency
;cpdprg1 : decoupling during recoupling, e.g. cw13
;cpdprg2 : decoupling during evolution periods, e.g. tppm15
;spnam0 : shape for contact pulse: ramp.100 
;l1 : number of rotor cycles for recoupling, any integer
;l2 : l2*2=l1 = (number of rotorcycles)
;ns : n*32
;FnMode: States-TPPI or STATES

;$COMMENT=SQ-DQ experiment with BABA for 2 rotor periods, cp excitation
;$CLASS=Solids
;$DIM=2D
;$TYPE=direct excitation
;$SUBTYPE=homonuclear correlation
;$OWNER=Bruker

define delay tau
  "tau=0.5s/cnst31-2*p1"

  "d0=1u"
  "in0=1s/cnst31"
  "d31=1s/cnst31"
  "l1=l2*2"
  "l0=2*l1"

;cnst11 : to adjust t=0 for acquisition, if digmod = baseopt
"acqt0=1u*cnst11"

1 ze
  d31
2 10m do:f2                    ;F2 decoupler off
  d1

#include <p15_prot.incl>
            ;make sure p15 does not exceed 10 msec	
            ;let supervisor change this pulseprogram if 
            ;more is needed
#include <aq_prot.incl>
            ;allows max. 50 msec acquisition time, supervisor
            ;may change  to max. 1s at less than 5 % duty cycle
            ;and reduced decoupling field
#include <rot_prot.incl>
            ;protect for too slow rotation

  1u fq=cnst21:f2
  (p3 pl12 ph1):f2             ;proton 90° pulse
  (p15 pl1 ph2):f1 (p15:sp0 ph10):f2    ;contact pulse with square or
                                        ;ramp shape ramp.100 on F2
  (p1 pl11 ph4):f1             ;90° pulse putting magnetization back to z-axis
                               ;for BABA double-quantum excitation
  100u cpds1:f2                ;switch to BABA RF condition
                               ;F2 decoupling during BABA: cw (or cwlg) or tppm

5 (p1 pl11 ph12):f1            ;BABA DQ excitation block
  tau
  (p1 ph12)
  (p1 ph13)
  tau
  (p1 ph14)
  (p1 ph12)
  tau
  (p1 ph12)
  (p1 ph14)
  tau
  (p1 ph13)
  lo to 5 times l2

  d0                           ;evolution of DQ coherence if more than 1 rotor period DQ excitation

7 (p1 ph23 ipp23)              ;BABA DQ reconversion block
  tau
  (p1 ph23 ipp23)
  lo to 7 times l0

  0.5u do:f2                   ;F2 decoupler off
  (p1 ph6):f1 (1u cpds2):f2    ;detection pulse, flip into the xy plane
                               ;F2 decoupling with TPPM or SPINAL during acquisition
  go=2 ph31

  1m do:f2                     ;F2 decoupler off
  10m mc #0 to 2 F1PH(ip12 & ip13 & ip14, id0)
HaltAcqu, 1m do:f2
  exit

ph1= 1 3
ph2= 0
ph10=0
ph4= 3 1
ph12=(8) 0 0 2 2 4 4 6 6       ; x  x  y  y -x -x -y -y
ph13=(8) 2 2 4 4 6 6 0 0       ; y  y -x -x -y -y  x  x
ph14=(8) 6 6 0 0 2 2 4 4       ;-y -y  x  x  y  y -x -x
ph23=    0 0 1 3 0 0 3 1       ; x  x  y -y  x  x -y  y
ph6 = 0 0 0 0 0 0 0 0 1 1 1 1 1 1 1 1 2 2 2 2 2 2 2 2 3 3 3 3 3 3 3 3
ph31= 0 0 2 2 0 0 2 2 1 1 3 3 1 1 3 3 2 2 0 0 2 2 0 0 3 3 1 1 3 3 1 1
  

References

  1. N. Chandrakumar
    1D double quantum filter NMR studies,
    in Annual Reports on NMR Spectroscopy, Graham A. Webb (Ed.), Elsevier, Amsterdam, vol. 67, pages 265-329 (2009).
    Abstract
     
  2. Mahdy M. Elmahdy, Mihail Mondeshki, Xi Dou, Hans-Jürgen Butt, Hans W. Spiess, Klaus Müllen, and George Floudas
    Slow kinetics of phase transformation in a dipole-functionalized discotic liquid crystal,
    J. Chem. Phys. 131, 114704/1-114704/9 (2009).
    Abstract
     
  3. Ingo Schnell
    Dipolar recoupling in fast-MAS solid-state NMR spectroscopy,
    Prog. Nucl. Magn. Reson. Spectrosc. 45, 145-207 (2004).
    Abstract
     
  4. V. M. Litvinov, M. Bertmer, L. Gasper, D. E. Demco, and B. Blümich
    Phase composition of block copoly(ether ester) thermoplastic elastomers studied by solid-state NMR techniques,
    Macromolecules 36, 7598-7606 (2003).
    Abstract
     
  5. Juraj Pivarč
    Application of the Multiple Quantum NMR Spectroscopy for Investigation of the Dipole-Dipole Couplings in Amorphous Polymers,
    Halle, 4 July 2000.
    Dissertation
     
  6. Stephan Dusold and Angelika Sebald
    Dipolar recoupling under magic-angle spinning conditions,
    in Annual Reports on NMR Spectroscopy, Graham A. Webb (Ed.), Elsevier, Amsterdam, vol. 41, pages 185-264 (2000).
    Abstract
     
  7. Ingo Schnell, Adonis Lupulescu, Siegfried Hafner, Dan E. Demco, and Hans W. Spiess
    Resolution enhancement in multiple-quantum MAS NMR spectroscopy,
    J. Magn. Reson. 133, 61-69 (1998).
    Abstract
     
  8. M. Feike, D. E. Demco, R. Graf, J. Gottwald, S. Hafner, and H. W. Spies
    Broadband multiple-quantum NMR spectroscopy,
    J. Magn. Reson. A 122, 214-221 (1996).
    Abstract
     
  9. Helen Geen, Jeremy J. Titman, Johannes Gottwald, and Hans W. Spiess
    Solid-state proton multiple-quantum NMR spectroscopy with fast magic angle spinning, (DRAMA, adamantane, polycarbonate)
    Chem. Phys. Lett. 227, 79-86 (1994).
    Abstract
     

(top)

[Contact me] - Last updated December 16, 2012
Solid-state NMR bibliography for
Aluminum-27
Antimony-121/123
Arsenic-75
Barium-135/137
Beryllium-9
Bismuth-209
Boron-11
Bromine-79/81
Calcium-43
Cesium-133
Chlorine-35/37
Chromium-53
Cobalt-59
Copper-63/65
Deuterium-2
Gallium-69/71
Germanium-73
Gold-197
Hafnium-177/179
Indium-113/115
Iodine-127
Iridium-191/193
Krypton-83
Lanthanum-139
Lithium-7
Magnesium-25
Manganese-55
Mercury-201
Molybdenum-95/97
Neon-21
Nickel-61
Niobium-93
Nitrogen-14
Osmium-189
Oxygen-17
Palladium-105
Potassium-39/41
Rhenium-185/187
Rubidium-85/87
Ruthenium-99/101
Scandium-45
Sodium-23
Strontium-87
Sulfur-33
Tantalum-181
Titanium-47/49
Vanadium-51
Xenon-131
Zinc-67
Zirconium-91



Copyright © 2002- pascal-man.com. All rights reserved.